[リモートでスクリプトを実行する]

リモートコンピュータ上で、スクリプトファイルを実行します。
実行するスクリプトファイルは、ローカルコンピュータに置いてください。
(ローカルのファイルを、リモートにコピーして実行するイメージです)
リモートでスクリプトを起動するには『HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows Script Host\Settings』に『Remote』という文字列値を値『1』で作成する必要があります。
悪用される可能性もありますので、公開サーバーには設定しない方が良いと思います。

【ソースコード】
[tips0093.vbs]
Option Explicit
On Error Resume Next

Dim objWshCtrl      ' WshController オブジェクト
Dim strRemotePC     ' リモートのコンピュータ名
Dim strScript       ' 実行するスクリプトファイル
Dim objExecCmd      ' 実行コマンド情報

Set objWshCtrl = WScript.CreateObject("WshController")
If Err.Number = 0 Then
    strRemotePC = "Comp01"
    strScript = "rmt_test.vbs"
    Set objExecCmd = objWshCtrl.CreateScript(strScript, strRemotePC)

    WScript.Echo strRemotePC & " で " & strScript & " を実行します。"
    objExecCmd.Execute
    Do While objExecCmd.Status = 1
        WScript.Sleep(1000)
    Loop
    WScript.Echo "終了しました。"
Else
    WScript.Echo "エラー: " & Err.Description
End If

Set objExecCmd = Nothing
Set objWshCtrl = Nothing
[rmt_test.vbs]
Option Explicit
On Error Resume Next

Dim objFSO      ' FileSystemObject
Dim objFile     ' ファイル書き込み用

Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
Set objFile = objFSO.OpenTextFile("C:\test.txt", 8, True)
objFile.WriteLine Now()
objFile.Close

Set objFile = Nothing
Set objFSO = Nothing

【実行結果】
C:\> cscript //NoLogo tips0093.vbs
Comp01 で rmt_test.vbs を実行します。
終了しました。