[レコードをXML形式で出力する]

Northwind.mdb の運送会社テーブルをXML形式でファイルに保存します。
定数定義ファイルの読み込み関数(IncludeAdoDefine)を使用しています。(ソースコードは省略します)

【ソースコード】
[tips0152.vbs]
Option Explicit
On Error Resume Next

Dim strDbName   ' データベース名
Dim blnRetCode  ' 戻り値
Dim objAdoCon   ' ADO 接続
Dim objAdoRset  ' ADO 選択行
Dim strSqlStmt  ' SQL 文
Dim strXmlFile  ' XML ファイル名

strDbName = "Northwind.mdb"
strXmlFile = "test.xml"

' ADO 定数の読み込み
blnRetCode = IncludeAdoDefine()
If blnRetCode = True Then
    Set objAdoCon = WScript.CreateObject("ADODB.Connection")
    If Err.Number = 0 Then
        objAdoCon.ConnectionString = _
            "Provider=Microsoft.Jet.OLEDB.4.0;" & _
            "Data Source=" & strDbName
        objAdoCon.Open

        Set objAdoRset = WScript.CreateObject("ADODB.Recordset")
        strSqlStmt = "SELECT * FROM 運送会社"
        objAdoRset.Open strSqlStmt, objAdoCon, adOpenStatic
        If Err.Number = 0 Then
            objAdoRset.Save strXmlFile, adPersistXML
            If Err.Number = 0 Then
                WScript.Echo strXmlFile & " を出力しました。"
            Else
                WScript.Echo "エラー:" & Err.Description
            End If
            objAdoRset.Close
        Else
            WScript.Echo "エラー:" & Err.Description
        End If
        objAdoCon.Close
    Else
        WScript.Echo "エラー:" & Err.Description
    End If
    Set objAdoCon = Nothing
End If

【実行結果】
C:\> cscript //NoLogo tips0152.vbs
test.xml を出力しました。