[キーを削除する]

登録されているキーと値を削除します。

【ソースコード】

[tips0092.vbs]
Option Explicit
On Error Resume Next

Dim objDic      ' Dictionary オブジェクト
Dim strDelKey   ' 削除するキー

strDelKey = "四国"

Set objDic = CreateObject("Scripting.Dictionary")
If Err.Number = 0 Then
    objDic.Add "北海道・東北", Array("北海道", "宮城", "福島", "岩手", "青森", "山形", "秋田")
    objDic.Add "関東", Array("東京", "神奈川", "千葉", "埼玉", "群馬", "山梨", "茨城", "栃木")
    objDic.Add "信越・北陸", Array("新潟", "長野", "福井", "石川", "富山")
    objDic.Add "中部", Array("愛知", "静岡", "岐阜", "三重")
    objDic.Add "関西", Array("大阪", "滋賀", "京都", "兵庫", "奈良", "和歌山")
    objDic.Add "中国", Array("広島", "岡山", "山口", "島根", "鳥取")
    objDic.Add "四国", Array("高松", "愛媛", "徳島", "高知")
    objDic.Add "九州・沖縄", Array("福岡", "佐賀", "長崎", "大分", "熊本", "鹿児島", "宮崎", "沖縄")

    WScript.Echo "現在の項目数は " & objDic.Count & " 個です。"

    ' キー削除
    objDic.Remove(strDelKey)
    WScript.Echo "『" & strDelKey & "』を削除しました。"
    WScript.Echo "残りの項目数は " & objDic.Count & " 個です。"

    ' 全削除
    objDic.RemoveAll
    WScript.Echo "全項目を削除しました。"
    WScript.Echo "残りの項目数は " & objDic.Count & " 個です。"
Else
    WScript.Echo "エラー: " & Err.Description
End If

Set objDic = Nothing

【実行結果】

C:\> cscript //NoLogo tips0092.vbs
現在の項目数は 8 個です。
『四国』を削除しました。
残りの項目数は 7 個です。
全項目を削除しました。
残りの項目数は 0 個です。