[フォルダを再帰的に作成する]

フォルダを再帰的に作成します。
親フォルダが存在しない場合も、一緒に作成されます。

【ソースコード】
[tips0083.vbs]
Option Explicit
On Error Resume Next

' フォルダを再帰的に作成する
Sub CreateFolderEx(ByVal strPath)
    Dim strParent   ' 親フォルダ

    strParent = objFSO.GetParentFolderName(strPath)
    If objFSO.FolderExists(strParent) = True Then
        If objFSO.FolderExists(strPath) <> True Then
            objFSO.CreateFolder strPath
        End If
    Else
        CreateFolderEx strParent
        objFSO.CreateFolder strPath
    End If
End Sub

Dim objFSO      ' FileSystemObject
Dim strFolder   ' 作成するフォルダ

strFolder = "C:\Tmp\test\next\テスト\new"
Set objFSO = WScript.CreateObject("Scripting.FileSystemObject")
If Err.Number = 0 Then
    CreateFolderEx(strFolder)
    If objFSO.FolderExists(strFolder) Then
        WScript.Echo strFolder & " を作成しました。"
    Else
        WScript.Echo strFolder & " を作成できませんでした。"
    End If
Else
    WScript.Echo "エラー: " & Err.Description
End If
Set objFSO = Nothing

【実行結果】
C:\> cscript //NoLogo tips0083.vbs
C:\Tmp\test\next\テスト\new を作成しました。